SAS维基百科 >>所属分类 >> SAS系统    使用指南    BASE模块    BASE程序   

proc datasets

标签: 暂无标签

顶[0] 发表评论(0) 编辑词条

【 功能】

            对数据集进行操作

【语法】

        PROC DATASETS <options>;
                      <COMMANDS> <options>;
         QUIT; RUN;

【举例】

1, 最简单的proc datasets应用
PROC DATASETS LIB =work;
QUIT;
RUN;
Datasets过程运行结果不输出,结果只有在日志里才能看到,如下:
PROC DATASETS LIB =work;
         目录
逻辑库引用名  WORK
引擎          V9
物理名        C:\DOCUME~1\ADMINI~1\LOCALS~1\Temp\SAS Temporary Files\_TD3908
文件名        C:\DOCUME~1\ADMINI~1\LOCALS~1\Temp\SAS Temporary Files\_TD3908
 #  名称     成员类型  文件大小  末次修改时间
 1  INVOICE  DATA          9216  2008年11月24日 21时40分26秒
2  ONE      DATA          9216  2008年11月24日 21时40分26秒
 QUIT;
结果输出到指定文件(results)中:
ods output members=results ;
proc datasets lib=work details memtype=data;
run;
ods output close;

2,用_all_选项来显示指定逻辑库的所有数据集的属性
PROC DATASETS LIB = work;
CONTENTS DATA =_all_; QUIT; RUN;
 
3, 逻辑库间数据集拷贝与移动
Copy:将所有数据集拷贝到另一逻辑库中
Move: 将所有数据集移动到另一逻辑库中
LIBNAME SS06 'C:\TEMP1';
PROC DATASETS;
COPY IN = work OUT =ss06;
QUIT;
RUN;
 
4, Select:选择要copy或move操作的数据集
5, Exclude:排除进行copy或move操作的数据集
 
PROC DATASETS;
     COPY IN = work OUT =ss06;
     exclude Invoice;
QUIT;
RUN;
 
6, 删除逻辑库的数据集
      Save:保留哪些数据集
      Delete:删除哪些数据集
      Kill:删除全部数据集
PROC DATASETS LIBRARY = work;  
   SAVE Invoice;
QUIT;
RUN;
 
PROC DATASETS LIBRARY = work;  
DELETE Invoice;
QUIT;
RUN;
 
PROC DATASETS LIBRARY = work  KILL;
QUIT;
RUN;

proc datasets lib=work ;delete a1-a3;run;
proc datasets lib=work ;delete a:;  run;
proc delete data=_all_;run;
 
7 ,使用append将数据集A加载到数据集B中
先准备数据:
Data a;
Set invoice(obs=6);
Run;
Data b;
Set invoice(firstobs=7);
Run;
如果A和B有不同的变量或相同变量的格式不一致,则可以用force选项强制执行,但不推荐用这个选项。
PROC DATASETS LIBRARY = WORK FORCE;
APPEND OUT = b   DATA = a;
QUIT; RUN;
 
8, 用change对数据集更名,下面是将数据集one更名为two
PROC DATASETS LIBRARY = work;
CHANGE one =two;
QUIT; RUN;
 
9, age对一组关联的变量进行改名
proc datasets library=daily nolist;
age one one1-one4;
quit; run;
这里对五个数据集进行操作,one,one1,one2,one3,one4,结果是删除one4,然后one3更名为one4,one2更名为one3,以此类推。
 
10, modify更改数据集属性,以及变量属性
PROC DATASETS LIBRARY = WORK;
MODIFY Invoice (LABEL = ‘NEW_MEMBER_LABEL’);
  RENAME custname = NEW_VARIABLE_NAME;
  LABEL  custname = LABEL_FOR_RENAMED_VARIABLE;
  FORMAT custname COMMA11.2;  
QUIT; RUN;
 
11, AUDIT STATEMENT 
PROC DATASETS LIB = work;
   AUDIT Invoice;
   INITIATE;
QUIT; RUN;  
PROC DATASETS LIB = work;
   AUDIT Invoice;
   SUSPEND;
QUIT; RUN;  
PROC DATASETS LIB = work;
   AUDIT Invoice;
   RESUME;
QUIT; RUN;  
PROC DATASETS LIB = work;
   AUDIT Invoice;
   TERMINATE;
QUIT; RUN;  
 
12,exchange数据集互换名字
PROC DATASETS LIB =work;
   EXCHANGE invoice =One;
QUIT; RUN; 
这时,原来的invoice换成了one,原来的one换成了invoice


参考资料
[1].  PROC DATASET:DATASETS过程介绍   http://blog.sina.com.cn/s/blog_5d3b177c0100bamo.html

附件列表


→如果您认为本词条还有待完善,请 编辑词条

上一篇verify函数 下一篇SCL LENGTH

词条内容仅供参考,如果您需要解决具体问题
(尤其在法律、医学等领域),建议您咨询相关领域专业人士。
0

收藏到:  

词条信息

sxlion
sxlion
超级管理员
最近编辑者 发短消息   

相关词条